Xrhrft

I have five values ​​that I would like to add them so that they can be equal to or less than 3000.

v1 = 140; v2 = 280; v3 = 420; v4 = 560; v5 = 700; goal = 3000;

Subsets [{v1, v2, v3, v4, v5}]

For example:

v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1

-> 2940

v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v2

-> 2940

v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v3

-> 2940

v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v4

-> 2940

v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v5

-> 2940

v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v2 + v2

-> 2940

v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v1 + v2 + v2 + v2

-> 2940

All are possibilities, among other possibilities.

Is there a feature that validates these possibilities?

a = {140, 280, 420, 560, 700};

results = Join @@ DeleteCases[

     IntegerPartitions[#, {1, ∞}, a] & /@ Range[3000],

     {}

     ];

And @@ Thread[Total /@ results <= 3000]

resulttable = Map[Lookup[Counts[#], a, 0] &, results];

resulttable // Short

True

{{1, 0, 0, 0, 0}, {0, 1, 0, 0, 0}, <<1341>> , {19, 1, 0, 0, 0}, {21, 0, 0, 0, 0}}

Append 1 to the list of vs and use FrobeniusSolve:

w = {v1, v2, v3, v4, v5, 1};

res = Rest[FrobeniusSolve[w, 3000]][[All, ;; 5]];

Length[res]

1345

Short @ res

{{0,0,0,0,1},{0,0,0,0,2},{0,0,0,0,3},{0,0,0,0,4},{0,0,0,1,0},<<1336>>,{19,0,0,0,0},{19,1,0,0,0},{20,0,0,0,0},{21,0,0,0,0}}

And @@ Thread[Total /@ res <= 3000]

True

Up to ordering, res is the same as Henrik's resulttable:

Sort[res] == Sort[resulttable]

True

An alternative way to use IntegerPartitions using w:

res2 = DeleteCases[Rest@IntegerPartitions[3000, All, w], 1, 2];

Length@res2

1345

restab = Map[Lookup[Counts[#], Most @ w, 0] &] @ res2;

Sort[res] == Sort[restab]

True

To get the totals that can be obtained using vs:

Sort[DeleteDuplicates[res.Most[w]]] (* or *)

Sort[3000 - DeleteDuplicates@Rest[FrobeniusSolve[w, 3000]][[All, -1]]]

{140, 280, 420, 560, 700, 840, 980, 1120, 1260, 1400, 1540, 1680,
1820, 1960, 2100, 2240, 2380, 2520, 2660, 2800, 2940}

Sort @ Counts[res.Most[w]]

<|140 -> 1, 280 -> 2, 420 -> 3, 560 -> 5, 700 -> 7, 840 -> 10,
980 -> 13, 1120 -> 18, 1260 -> 23, 1400 -> 30, 1540 -> 37,
1680 -> 47, 1820 -> 57, 1960 -> 70, 2100 -> 84, 2240 -> 101,
2380 -> 119, 2520 -> 141, 2660 -> 164, 2800 -> 192, 2940 -> 221|>

v1 = 140; v2 = 280; v3 = 420; v4 = 560; v5 = 700; goal = 3000;

Select[Subsets[{v1, v2, v3, v4, v5}], Total[#] <= goal &]

Are you sure your "goal" is 3000? Every subset totals less than that.

And what does 21 * v1 in your question refer to? What is $21$, and why multiplication?

a = {140, 280, 420, 560, 700};

coef = Tuples[Range[0, 21], 5];

vec = coef.a;



Extract[coef, Position[Ramp[vec - 3000], 0]] // Short

{{0,0,0,0,0},{0,0,0,0,1},{0,0,0,0,2},{0,0,0,0,3},{0,0,0,0,4},{0,0,0,1,0},<<1335>>,{18,1,0,0,0},{19,0,0,0,0},{19,1,0,0,0},{20,0,0,0,0},{21,0,0,0,0}}

Pick[vec, Ramp[vec - 3000], 0] // Short

{0,700,1400,2100,2800,560,1260,1960,2660,1120,1820,2520,1680,2380,<<1318>>,2940,2800,2380,2940,2800,2660,2940,2520,2940,2800,2660,2940,2800,2940}